Oblivion Game Data

scn MQ06RumaScript

short spokeToPC
float resurrectTimer		; used to resurrect her in Paradise
short dead

begin onStartCombat player
	setstage MQ06 46
end

Begin OnHit player
	setstage MQ06 46
End

Begin OnAlarm 3, player
	setstage MQ06 46
End

Begin OnAlarm 1, player
	setstage MQ06 46
End

begin OnPackageDone MQ15RumaWaitAtThrone
	look player
end
 
begin gamemode

if getstage MQ06 < 51
	if ( MQ06.convTimer <= 0 && MQ06.speaker == 2  )
		; time to talk
		set MQ06.convTimer to SayTo MankarCamoranRef MQ06MankarSpeech
		set MQ06.convTimer to MQ06.convTimer + 1
	endif

	if ( MQ06.convTimer <= 0 && MQ06.speaker == 4 )
		; time to talk
		set MQ06.convTimer to SayTo player MQ06MankarSpeech
		set MQ06.convTimer to MQ06.convTimer + 1
	endif
endif

if spokeToPC == 0 && getstagedone MQ06, 41 == 0 && getstage MQ06 == 50 && getdistance player < 400
	startConversation player
	set spokeToPC to 1
endif

if spokeToPC < 2 && getstage MQ06 == 60 && getdead == 0
	say MQ06MythicDawnAlarm
	set spokeToPC to 2
endif

; greet player in Paradise
if getstage MQ15 >= 70 && getstage MQ15 < 75 && getdistance player < 800
	setstage MQ15 75
endif

if dead > 0
if getstage MQ15 >= 70 && getstage MQ15 < 89
	if resurrectTimer > 0
		set resurrectTimer to resurrectTimer - getsecondsPassed
	else
		if dead == 1
			; start resurrection
			set dead to 2
			set resurrectTimer to 2
			pme BABO
			;pms CHAMELEON
		elseif dead == 2
			; resurrect
			set dead to 0
			resurrect
			moveto MQ15RumaResurrectMarker
			MQ15RumaResurrectCloud.activate MQ15RumaResurrectMarker 1
			pme BABO
			;sms CHAMELEON
		endif
	endif
endif
endif

end

begin OnDeath
	if getstage mq15 >= 70
		set resurrectTimer to 20
		set dead to 1

		; Mankar will attack if you kill both Ruma and Raven
		if MQ15RavenRef.getdead == 1 && getstage mq15 >= 80
			setstage mq15 85
		endif
	endif
end