| SCTX |
scriptname MS45Script
short startDay ; set to gameday that player first speaks to Dar-Ma
short innkeeperLied ; set to 1 if innkeeper denies knowing about Dar-Ma
short traderLied ; set to 1 if trader denies knowing about Dar-Ma
short foundDiary ; set to 1 when player finds diary
short foundHorse ; set to 1 when player finds horse
short enabled ; used to enable quest objects
short untied ; used to track when you untie Dar-Ma
short unlockCell ; used to track when you unlock the cell door
short thankedPC ; set to 1 after Dar-Ma thanks PC for rescue
short warnedPC ; set to 1 after someone warns PC to leave Hackdirt
short followPC ; set to 1 while someone is following the PC
short attackPC ; set when alarm is given to attack the player
float spawnTimer
ref spawnMarker
begin gamemode
if spawnTimer > 0
set spawnTimer to spawnTimer - getsecondspassed
elseif spawnMarker != 0
spawnMarker.placeatme HackdirtBrethrenMonster
set spawnMarker to 0
endif
; timer for triggering Dar-Ma to disappear 2 days after you first speak to her
if getstage MS45 == 0 && startDay > 0
; don't move her until player is not in Chorrol, so we don't see her disappear
if ( gameDaysPassed - startDay ) > 2 && ( player.GetInCell Chorrol == 0 )
if ( VlanhonderMoslinRef.GetDead == 1 ) || ( EtiraMoslinRef.GetDead == 1 )
; if either are dead, cancel quest completely
set startDay to 0
stopQuest MS45
else
; move her to Hackdirt
SetStage MS45, 1
set startDay to gameDaysPassed
endif
endif
endif
; wait 2 days for the news to spread
if getstage MS45 == 1
if ( gameDaysPassed - startDay ) > 1
SetStage MS45, 2
endif
endif
; trigger Dar-Ma to speak to you when you escape from Hackdirt
if thankedPC == 0 && untied == 1
if DarMaRef.GetInCell Hackdirt == 0
DarMaRef.StartConversation player, MS45DarMaGoHome
set thankedPC to 1
endif
endif
; *************************************************************************
; initialization stuff after this
; *************************************************************************
if enabled > 0
return
endif
if enabled == 0
jivhirielref.moddisposition player 20 ; jiv hiriel is friendlier than the rest of Hackdirt
etiramoslinref.forceav mercantile 100 ; crappy prices at Moslin's Dry Goods!
set enabled to 1
endif
end
|