Oblivion Game Data

scn NDGukimirSCRIPT

short JoinedOrder
short	DoOnce

short GeimundSpar
short GukimirSpar
short SparUpdate

; clear follower variables if I'm the follower when I die
begin OnDeath
	if GetSelf == ND00.FollowerRef
		set ND00.FollowerRef to 0
		set ND00.Following to 0
		set ND00.FollowerClear to 1
	endif	

	if getstage ND10 >= 20 && getstage ND10 < 50
		set ND10.KnightsDead to ND10.KnightsDead + 1
		if ( ND00.KnightCount - ND10.KnightsDead ) <= 3
			set ND10.KnightFollow to 1
		endif	
	endif
	
end


begin OnPackageEnd NDGeimundToPriory
	if GetInFaction NDKnightsoftheNine == 0
		set ND00.KnightCount to ND00.KnightCount + 1
		if GetIsID NDGeimund == 1
			SetActorFullName "Sir Geimund"
			; no longer essential
			SetEssential NDGeimund 0
		else
			SetActorFullName "Sir Gukimir"
			; no longer essential
			SetEssential NDGukimir 0
		endif
		SetFactionRank NDKnightsoftheNine 0
		SetNoRumors 1
		removeallitems
		; knight equipment
		additem NDKnightsCuirass 1
		additem NDKnightsShield 1
		additem ChainmailBoots 1
		additem ChainmailGauntlets 1
		additem ChainmailGreaves 1
		additem ChainmailHelmet 1
		additem LL0NPCWeaponLongswordLvl100 1
		additem LL0NPCWeaponBowLvl100 1
		additem Arrow3Silver 5
		; make sure they have clothes to sleep in
		additem LowerPants05 1
		additem LowerShirt06 1
		additem LowerShoes01 1
		equipitem NDKnightsCuirass
		equipitem NDKnightsShield 
		equipitem ChainmailBoots 
		equipitem ChainmailGauntlets 
		equipitem ChainmailGreaves 
		equipitem ChainmailHelmet 
	endif
end

BEGIN OnActivate

	if ( ND10.TimeStopped == 1 ) && ( Player.GetInCell NDGarlasMalatar02a == 1 )
		message "The time stop effect prevents you from interacting with the Knights."
	else
			activate
	endif

END

begin OnStartCombat player
	return
end

begin OnStartCombat
	Say NDKnightsStartCombat
end

Begin GameMode

if ( GetIsID NDGukimir == 1 )
	if ( GukimirSpar == 0 )
		if ( GetDistance NDGukimirSparMarker < 200 )
			set GukimirSpar to 1
		endif
	elseif ( GukimirSpar == 1 ) 
		if ( GetDistance NDGukimirSparMarker > 200 )
			set GukimirSpar to 0
			set SparUpdate to 0
		endif
	endif
endif

if ( GetIsID NDGeimund == 1 )
	if ( GeimundSpar == 0 )
		if ( GetDistance NDGeimundSparMarker < 200 )
			set GeimundSpar to 1
		endif
	elseif ( GeimundSpar == 1 ) 
		if ( GetDistance NDGeimundSparMarker > 200 )
			set GeimundSpar to 0
			set SparUpdate to 0
		endif
	endif
endif

if ( SparUpdate == 0 )
	if ( NDGukimirRef.GukimirSpar == 1 )
		if ( NDGeimundRef.GeimundSpar == 1 )
			evp
			set SparUpdate to 1
		endif
	endif
endif


End